Encuentra la clave de producto de Windows
Tres formas legales de ver la clave de producto de Windows: con el Símbolo del sistema, con comandos de licencia y con un script que lee el registro.
Nota: esta guía es para recuperar la clave de tu propia licencia. Usa siempre software legal.
¿Dónde estaba la clave antes?
Hace años la clave venía en una etiqueta pegada en la parte de atrás del computador. Es un código de 25 caracteres que se ve así:
PRODUCT KEY: XXXXX-XXXXX-XXXXX-XXXXX-XXXXX
1. Con el Símbolo del sistema (CMD)
- Busca CMD en Windows y ábrelo como administrador.
- Escribe este comando y pulsa Enter:
wmic path softwarelicensingservice get OA3xOriginalProductKey
Si el equipo trae la licencia grabada de fábrica, aparece la clave completa.
2. Información de la licencia
slmgr /dli: muestra la licencia y los últimos 5 caracteres de la clave.slmgr /dlv: muestra información más detallada.slmgr /xpr: dice si Windows está activado de forma permanente o cuándo vence.
3. Con un script que lee el registro
Abre el Bloc de notas, pega este código y guárdalo como productkey.vbs. Al abrirlo con doble clic muestra el nombre del producto, el ID y la clave instalada, y te ofrece guardarla en un archivo en el escritorio.
Option Explicit
Dim objshell,path,DigitalID, Result
Set objshell = CreateObject("WScript.Shell")
'Set registry key path
Path = "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\"
'Registry key value
DigitalID = objshell.RegRead(Path & "DigitalProductId")
Dim ProductName,ProductID,ProductKey,ProductData
'Get ProductName, ProductID, ProductKey
ProductName = "Product Name: " & objshell.RegRead(Path & "ProductName")
ProductID = "Product ID: " & objshell.RegRead(Path & "ProductID")
ProductKey = "Installed Key: " & ConvertToKey(DigitalID)
ProductData = ProductName & vbNewLine & ProductID & vbNewLine & ProductKey
'Show messbox if save to a file
If vbYes = MsgBox(ProductData & vblf & vblf & "Save to a file?", vbYesNo + vbQuestion, "BackUp Windows Key Information") then
Save ProductData
End If
'Convert binary to chars
Function ConvertToKey(Key)
Const KeyOffset = 52
Dim isWin8, Maps, i, j, Current, KeyOutput, Last, keypart1, insert
'Check if OS is Windows 8
isWin8 = (Key(66) \ 6) And 1
Key(66) = (Key(66) And &HF7) Or ((isWin8 And 2) * 4)
i = 24
Maps = "BCDFGHJKMPQRTVWXY2346789"
Do
Current= 0
j = 14
Do
Current = Current* 256
Current = Key(j + KeyOffset) + Current
Key(j + KeyOffset) = (Current \ 24)
Current=Current Mod 24
j = j -1
Loop While j >= 0
i = i -1
KeyOutput = Mid(Maps,Current+ 1, 1) & KeyOutput
Last = Current
Loop While i >= 0
If (isWin8 = 1) Then
keypart1 = Mid(KeyOutput, 2, Last)
insert = "N"
KeyOutput = Replace(KeyOutput, keypart1, keypart1 & insert, 2, 1, 0)
If Last = 0 Then KeyOutput = insert & KeyOutput
End If
ConvertToKey = Mid(KeyOutput, 1, 5) & "-" & Mid(KeyOutput, 6, 5) & "-" & Mid(KeyOutput, 11, 5) & "-" & Mid(KeyOutput, 16, 5) & "-" & Mid(KeyOutput, 21, 5)
End Function
'Save data to a file
Function Save(Data)
Dim fso, fName, txt,objshell,UserName
Set objshell = CreateObject("wscript.shell")
'Get current user name
UserName = objshell.ExpandEnvironmentStrings("%UserName%")
'Create a text file on desktop
fName = "C:\Users\" & UserName & "\Desktop\WindowsKeyInfo.txt"
Set fso = CreateObject("Scripting.FileSystemObject")
Set txt = fso.CreateTextFile(fName)
txt.Writeline Data
txt.Close
End Function
¿Viste el video? Encuentra más tutoriales en nuestro canal de YouTube o vuelve a todos los tutoriales.